DESCRIPTION = "Open source network boot firmware"
HOMEPAGE = "http://ipxe.org"
LICENSE = "GPLv2"
DEPENDS = "binutils-native perl-native syslinux mtools-native cdrtools-native"
LIC_FILES_CHKSUM = "file://../COPYING;md5=8ca43cbc842c2336e835926c2166c28b"

SRCREV = "8c43891db4eb131d019360ccfb619f235b17eb58"
PV = "gitr${SRCPV}"
PR = "r1"

FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
SRC_URI = "git://git.ipxe.org/ipxe.git;protocol=https file://dhcp_retry.ipxe"

FILES_${PN} = " \
    /srv/tftp/undionly.kpxe \
    /srv/tftp/efi32/boot.efi \
    /srv/tftp/efi64/boot.efi \
"

EXTRA_OEMAKE = "NO_WERROR=1"
#PARALLEL_MAKE=""
TARGET_CFLAGS += "-fno-PIE"

S = "${WORKDIR}/git/src"

do_configure() {
   sed -i s#^ISOLINUX_BIN[\ \\t]*=.*#ISOLINUX_BIN\ =\ ${STAGING_DIR_TARGET}/usr/lib/syslinux/isolinux.bin# arch/i386/Makefile
}

do_compile() {
   oe_runmake \
    EMBED=${WORKDIR}/dhcp_retry.ipxe \
    bin-i386-efi/ipxe.efi \
    bin-x86_64-efi/ipxe.efi \
    bin/undionly.kpxe
}

do_install() {
    install -d ${D}/srv/tftp/efi32
    install -d ${D}/srv/tftp/efi64
    install ${S}/bin/undionly.kpxe ${D}/srv/tftp
    install ${S}/bin-i386-efi/ipxe.efi ${D}/srv/tftp/efi32/boot.efi
    install ${S}/bin-x86_64-efi/ipxe.efi ${D}/srv/tftp/efi64/boot.efi
}